Esta série de posts apresentará a simulação realizada com os parâmetros de uma máquina CC de 5 HP, em configuração shunt, operando como motor, a fim de extrair o comportamento dinâmico na partida e na mudança abrupta da carga no eixo.
Para tanto, as equações diferenciais que
descrevem a máquina foram solucionadas numericamente utilizando-se o software
Scilab, em sua versão 5.5.1, através de bibliotecas de funções aplicadas a este
tipo de resolução. Para esta simulação se
considerou um torque de carga proporcional à velocidade do rotor, de forma que o
torque nominal ocorresse na velocidade nominal, sendo desprezado qualquer
coeficiente de amortecimento.
Nesta primeira parte, apresentaremos o código fonte em Scilab desconsiderando a presença de qualquer método de partida, ou seja, sendo aplicada a máquina seu valor nominal de tensão, tendo a corrente de armadura limitada apenas pela resistência de armadura. Neste código consta, além dos parâmetros da máquina CC em questão e da carga mecânica, as equações diferenciais que regem o comportamento dinâmico da máquina, representadas através da função fcc. Para maiores detalhes sobre a obtenção de tais equações, sugere-se uma consulta a [1].
Abaixo o código fonte:
// Programa de Simulação de Partida para máquina CC
// Autor: Djan Rosário
// Data: 14/06/15
clear,clc,clf
// Dados do Motor
Rf = 240; // Resistência do enrolamento de campo
LFF = 120; // Indutância própria da bobina de campo
LAF = 1.8; // Indutância mútua da bobina de campo e armadura
ra = 0.6; // Resistência do enrolamento de armadura
LAA = 0.012; // Indutância própria da bobina de armadura
// Dados de Entrada
Vf = 240; // Tensão de campo
Va = 240; // Tensão de armadura (igual a de campo - shunt)
J = 1; //momento de inércia da máquina e da carga
// Dados da Carga Mecânica
BL = 0.2287;
function ifdot=ff(t,iff)
ifdot = -(Rf/LFF)*iff + Vf/LFF;
endfunction
iff0 = 0;
t0 = 0;
t = 0:0.01:10;
ifsol = ode(iff0,t0,t,ff);
//Função das equações diferenciais de espaço de estado da Máquina
function idot = fcc(t,i)
idot(1)=-(ra/LAA)*i(1) - (LAF/LAA)*(Vf/Rf)*i(2) + Va/LAA;
idot(2)= (LAF/J)*(Vf/Rf)*i(1) - (1/J)*BL*i(2);
endfunction
// Condições Iniciais
i0 = [0;0];
t0 = 2;
// Variável temporal com passo de 0.01
tn = 2:0.01:10;
// Resolução Numérica das Equações Diferenciais
isol = ode(i0,t0,tn,fcc);
t = [0:0.01:1.99 tn];
isol = [zeros(2,200) isol];
// Cálculo do Torque Eletromagnético
Te = LAF*ifsol.*isol(1,:);
//Te = [zeros(1,200) Te];
//Plotagem dos Resultados
subplot(411),plot2d(t,ifsol,2),xtitle("Corrente de Campo","t","If [A]"),xgrid
subplot(412),plot2d(t,isol(1,:),3),xtitle("Corrente de Armadura","t","Ia [A]"),xgrid
subplot(413),plot2d(t,Te,7),xtitle("Torque","t","T [N.m]"),xgrid
subplot(414),plot2d(t,isol(2,:),5),xtitle("Velocidade do Rotor","t","Wr [rad/s]"),xgrid
Os resultados desta simulação são apresentados na figura abaixo:
Observe o alto valor da corrente de armadura na partida (curva verde), muito superior ao seu valor de regime, em torno de 16 A. No próximo post da série, simularemos a situação envolvendo o emprego de três resistores de partida, a fim de tentar limitar a corrente de armadura na partida a um valor não superior ao dobro de seu valor nominal.
Referências:
[1]
KRAUSE, Paul C. WASYNCZUK, Oleg. SUDHOFF,
Scott D.Analysis of Electric Machinery and Drive Systems.
